运算放大器电路的SPIC 噪声分析介绍

用 TINA 分析第三部分中的电路

图 4.17 显示了采用 Tina SPICE 的 OPA627 建模原理图。请注意，第四部分讨论了通过用分离噪声源和通用运算放大器开发自己的模型来对噪声进行适当建模的方法，此外，电阻 Rf 和 R1 匹配于第三部分中的示例电路。



图 4.17：OPA627 电路示例

我们可从下来菜单中选择 “分析\噪声分析”，进行 Tina SPICE 噪声分析，这将生成噪声分析表。我们可在噪声分析表上选择 “输出噪声” 和 “总噪声”选项。“输出噪声” 选项将针对所有测试点（即带仪表的节点）生成噪声频谱密度图。“总噪声”将生成功率谱密度曲线图积分结果。我们可通过总噪声曲线明确电路的均方根输出噪声电压。图 4.18 显示了如何执行噪声分析。



图 4.18：运行噪声分析

图 4.19 和图 4.20 显示了 TINA 噪声分析的结果。图 4.19 给出了放大器输出处的噪声频谱密度（即输出噪声）。该曲线结合了所有噪声源，并包括噪声增益的效果和噪声带宽。图 4.20 显示了给定带宽下放大器输出处的总噪声。我们也可以求功率频谱密度曲线的积分（即电压频谱密度的平方），从而推导出该曲线。请注意，该曲线在高频下为常量，即323uVrms。这一结果与第三部分中计算得出的均方根噪声相匹配（我们计算所得的噪声为324uV）。还要注意，该噪声为常量，这是由于运算放大器的带宽限制使然。



　图 4.19：输出噪声图结果



图 4.20：总噪声图结果

本文总结和下文内容提要

在本文中，我们介绍了称作 TINA SPICE 的电路模拟套件。我们用 TINA 开发了一套简单的测试步骤来检查运算放大器模型是否可以准确对噪声进行建模。在某些情况下，有的模型不能通过测试，因此，我们就用分离噪声源和通用运算放大器开发出了我们自己的模型。我们还用 TINA 来计算第三部分实际分析中所用的示例电路的噪声。在第五部分，我们将分析测试噪声的方法，特别是要对此前章节中的噪声计算结果进行物理测量。

关于作者：

Arthur Kay是 TI 的高级应用工程师。他专门负责传感器信号调节器件的支持工作。他于 1993 年毕业于佐治亚理工学院 (Georgia Institute of Technology)，并获得电子工程硕士学位。

附录 4.1：电压噪声宏

* BEGIN PROG NSE NANO VOLT/RT-HZ
.SUBCKT VNSE 1 2
* BEGIN SETUP OF NOISE GEN - NANOVOLT/RT-HZ
* INPUT THREE VARIABLES
* SET UP VNSE 1/F
* NV/RHZ AT 1/F FREQ
.PARAM NLF=15
* FREQ FOR 1/F VAL
.PARAM FLW=10
* SET UP VNSE FB
* NV/RHZ FLATBAND
.PARAM NVR=4.5
* END USER INPUT
* START CALC VALS
.PARAM GLF={PWR(FLW,0.25)*NLF/1164}
.PARAM RNV={1.184*PWR(NVR,2)}
.MODEL DVN D KF={PWR(FLW,0.5)/1E11} IS=1.0E-16
* END CALC VALS
I1 0 7 10E-3
I2 0 8 10E-3
D1 7 0 DVN
D2 8 0 DVN
E1 3 6 7 8 {GLF}
R1 3 0 1E9
R2 3 0 1E9
R3 3 6 1E9
E2 6 4 5 0 10
R4 5 0 {RNV}
R5 5 0 {RNV}
R6 3 4 1E9
R7 4 0 1E9
E3 1 2 3 4 1
C1 1 0 1E-15
C2 2 0 1E-15
C3 1 2 1E-15
.ENDS
·END PROG NSE NANOV/RT-HZ

附录 4.2：电流噪声宏

* BEGIN PROG NSE FEMTO AMP/RT-HZ
.SUBCKT FEMT 1 2
* BEGIN SETUP OF NOISE GEN - FEMPTOAMPS/RT-HZ
* INPUT THREE VARIABLES
* SET UP INSE 1/F
* FA/RHZ AT 1/F FREQ
.PARAM NLFF=2.5
* FREQ FOR 1/F VAL
.PARAM FLWF=0.001
* SET UP INSE FB
* FA/RHZ FLATBAND
.PARAM NVRF=2.5
* END USER INPUT
* START CALC VALS
.PARAM GLFF={PWR(FLWF,0.25)*NLFF/1164}
.PARAM RNVF={1.184*PWR(NVRF,2)}
.MODEL DVNF D KF={PWR(FLWF,0.5)/1E11} IS=1.0E-16
* END CALC VALS
I1 0 7 10E-3
I2 0 8 10E-3
D1 7 0 DVNF
D2 8 0 DVNF
E1 3 6 7 8 {GLFF}
R1 3 0 1E9
R2 3 0 1E9
R3 3 6 1E9
E2 6 4 5 0 10
R4 5 0 {RNVF}
R5 5 0 {RNVF}
R6 3 4 1E9
R7 4 0 1E9
G1 1 2 3 4 1E-6
C1 1 0 1E-15
C2 2 0 1E-15
C3 1 2 1E-15
.ENDS
* END PROG NSE FEMTO AMP/RT-HZ