PIC单片机计时秒表程序设计

ORG 0X00
GOTO MAIN
ORG 0X08
GOTO CLKINT ;转向中断服务程序
ORG 0X30

;数字到段码的转换子程序(最好放在程序开头，避免超过2K的空间发生跨页读表)
;************不带小数点的共阳极码表**************
CONVERT ADDWF PCL，1
RETLW 0XC0 ;0，显示段码与具体的硬件连接有关
RETLW 0XF9 ;1
RETLW 0XA4 ;2
RETLW 0XB0 ;3
RETLW 0X99 ;4
RETLW 0X92 ;5
RETLW 0X82 ;6
RETLW 0XD8 ;7
RETLW 0X80 ;8
RETLW 0X90 ;9
RETLW 0X88 ;A
RETLW 0X83 ;B
RETLW 0XC6 ;C
RETLW 0XA1 ;D
RETLW 0X86 ;E
RETLW 0X8E ;F
RETLW 0X7F ;"."
RETLW 0XBF ;"-"
RETLW 0X89 ;H
RETLW 0XFF ;DARK
RETURN

;*********带小数点的共阳极码表***********
CONVERT2 ADDWF PCL，1
RETLW 0X40 ;0
RETLW 0X79 ;1
RETLW 0X24 ;2
RETLW 0X30 ;3
RETLW 0X19 ;4
RETLW 0X12 ;5
RETLW 0X02 ;6
RETLW 0X78 ;7
RETLW 0X00 ;8
RETLW 0X10 ;9
RETURN

;***********SPI发送显示子模块************
TRANSMIT
CLRF PORTA ;LACK送低电平，为锁存做准备
MOVWF SSPBUF ;启动发送
WAIT NOP
BTFSS PIR1，SSPIF
GOTO WAIT ;等待发送结束
BCF PIR1，SSPIF ;清除中断标志
RETURN

;***********显示子程序模块************
DISPLAY
MOVLW 0X01
MOVWF LEDF
MOVLW 0XA0
MOVWF FSR0L
AGAINXIAN
MOVF LEDF，W
SUBLW 0X03
BTFSS STATUS，Z
GOTO XIANB
MOVF INDF0，W
CALL CONVERT2 ;若是个位，则查带小数点的码表
GOTO TRAN
XIANB MOVF INDF0，W
CALL CONVERT
TRAN CALL TRANSMIT ;发送一个显示数据
INCF FSR0L
INCF LEDF
MOVF LEDF，W
SUBLW 0X05
BTFSS STATUS，Z
GOTO AGAINXIAN
MOVLW 0X01
MOVWF LEDF
XIANDARK
MOVLW 0X27
CALL CONVERT
CALL TRANSMIT
INCF LEDF
MOVF LEDF，W
SUBLW 0X05
BTFSS STATUS，Z
GOTO XIANDARK ;显示4个"DARK"
BSF PORTA，5 ;最后给一个锁存信号，代表一次显示任务完成
RETURN
;********** S0计数溢出处理子程序***************
CS0
CLRF S0
INCF S1
RETURN
;********** S1计数溢出处理子程序***************
CS1
CLRF S1
INCF S2
RETURN
;********** S2计数溢出处理子程序***************
CS2
CLRF S2
INCF S3
RETURN
;********** S3计数溢出处理子程序***************
CS3
CLRF S3
RETURN
;***********时钟中断服务程序*******************
CLKINT
MOVWF XW_TEMP ;保存W的值
SWAPF STATUS，W
MOVWF XHOSTS ;暂存STATUS的值
MOVF FSR0L，W
MOVWF HOSTF ;保存FSR0L的值。以上程序为中断现场保护
MOVLW 0X13
MOVWF TMR0L ;对TMR0L写入一个调整值，因为写入
;TMR0L后接着的两个周期不能增量
BCF INTCON，T0IF ;清除中断标志
INCF SREG
MOVF SREG，W
SUBLW 0X28 ;TMR0L 每250us中断一次
BTFSS STATUS，Z ;其中断40次后才执行对S0 S1 S2 S3 的操作
GOTO TIFAN
CLRF SREG
INCF S0
MOVF S0，W
SUBLW 0X0A
BTFSC STATUS，Z
CALL CS0
MOVF S1，W
SUBLW 0X0A
BTFSC STATUS，Z
CALL CS1
MOVF S2，W
SUBLW 0X0A
BTFSC STATUS，Z
CALL CS2
MOVF S3，W
SUBLW 0X0A
BTFSC STATUS，Z
CALL CS3
TIFAN
MOVF HOSTF，W ;以下为中断现场恢复
MOVWF FSR0L ;恢复间接寻址指针FSR0L的值
SWAPF XHOSTS，W
MOVWF STATUS ;恢复STATUS的值
SWAPF XW_TEMP，1
SWAPF XW_TEMP，W ;恢复W的值
RETFIE
;*********** TMR0初始化子程序***************
CLKINSUB
MOVLW 0XCF
MOVWF T0CON ;设定TMR0L工作于8位定时器方式
;内部时钟，TMR0不用分频
BCF INTCON，TMR0IF ;清除TMR0的中断标志
BCF INTCON，GIE ;总中断禁止
BSF INTCON，TMR0IE ;TMR0中断允许
BSF INTCON2，2 ;TMR0中断高优先级
BSF RCON，7 ;使能中断优先级
RETURN
;***************系统初始化子程序*****************
MAINSUB
BCF TRISA，5 ;置RA5为输出方式，以输出锁存信号
BCF TRISB，1
BCF TRISA，3
BCF TRISE，0
BCF TRISE，1
BSF TRISB，4 ;设置与键盘有关的各口的输入输出方式
BCF TRISC，5
BCF TRISC，3 ;设置SCK与SDO为输出方式
BCF INTCON，GIE ;关闭所有中断
MOVLW 0XC0
MOVWF SSPSTAT ;设置SSPSTAT寄存器
MOVLW 0X30
MOVWF SSPCON1 ;设置SPI的控制方式，允许SSP方式，
;并且时钟下降沿发送，与"74HC595当
;其SCLK从低到高平跳变时，串行输入数据
;(DI)移入寄存器"的特点相对应
RETURN ;返回
;***********键扫描子程序********************
KEYSCAN
BCF PORTB，1
BCF PORTA，3
BCF PORTE，0
BCF PORTE，1 ;送低电平至K1，K2，K3，K4
RETURN
;*********键盘去抖子程序(8ms的延时)******************
KEYDELAY
MOVLW 0X0A
MOVWF DEYH
AGAIN2 MOVLW 0XFF
MOVWF DEYL
AGAIN1 DECFSZ DEYL，1
GOTO AGAIN1
DECFSZ DEYH，1
GOTO AGAIN2 ;具体程序语句参考3. 2节
RETURN
;*************显示缓冲区处理子程序****************
XIANHUAN
MOVLW 0XA0
MOVWF FSR0L
RLNCF S0，0
MOVWF TEMP
INCF TEMP，0
MOVWF INDF0
INCF FSR0L
RLNCF S1，0
MOVWF TEMP
INCF TEMP，0
MOVWF INDF0
INCF FSR0L
RLNCF S2，0
MOVWF TEMP
INCF TEMP，0
MOVWF INDF0
INCF FSR0L
RLNCF S3，0
MOVWF TEMP
INCF TEMP，0
MOVWF INDF0
RETURN
;**************主程序******************
MAIN NOP
CALL MAINSUB ;系统初始化
CALL CLKINSUB ;调用时钟初始化子程序
DENJIAN BCF INTCON，GIE
CLRF S0
CLRF S1
CLRF S2
CLRF S3
CLRF SREG
CLRF LEDF ;S0=S1=S2=S3=0
CALL XIANHUAN ;把S3、S2、S1、S0的值装入显示缓冲区
CALL DISPLAY ;显示
DENAN BCF INTCON，GIE ;关中断
CALL KEYSCAN ;进行键扫描
BTFSS PORTB，4
GOTO XIAODOU1 ;如起始键按下，则消抖动
GOTO DENAN ;如起始键没按下，则继续等待
XIAODOU1
CALL KEYDELAY ;延时消抖动
CALL KEYSCAN ;再次进行键扫描
BTFSC PORTB，4
GOTO DENAN ;若为干扰，则再次等待键按下
CLRF S0
CLRF S1
CLRF S2
CLRF S3
CLRF SREG ;设置新一次计时的初始条件
WAITS CALL KEYSCAN
BTFSS PORTB，4
GOTO WAITS ;为了防止按键过于灵敏，等键松开后再进行
;下面的操作
BSF INTCON，GIE ;开总中断
HERE CALL XIANHUAN ;显示缓冲区处理
CALL DISPLAY ;即时更新显示内容
CALL KEYSCAN
BTFSS PORTB，4
GOTO XIAODOU ;若停止计时键按下，则消抖
GOTO HERE ;若停止计时键没按下，则继续等待中断计时
XIAODOU
CALL DISPLAY ;利用消抖动时间调用显示程序
CALL DISPLAY
CALL DISPLAY
CALL DISPLAY
CALL DISPLAY
CALL DISPLAY
CALL DISPLAY
CALL DISPLAY
CALL DISPLAY
CALL KEYSCAN
BTFSC PORTB，4
GOTO HERE ;若为干扰，则继续等待停止键按下
BCF INTCON，GIE ;若停止键按下，则禁止中断
CALL DISPLAY ;若不为干扰，则禁止中断，更新显示内容
WAITR CALL KEYSCAN
BTFSS PORTB，4
GOTO WAITR ;为了防止按键过于灵敏，等键松开后再进行
;下面的操作
DENDAI CALL KEYSCAN
BTFSC PORTB，4
GOTO DENDAI ;循环进行键扫描，等待清0键按下
CALL KEYDELAY ;延时消抖
CALL KEYSCAN
BTFSC PORTB，4
GOTO DENDAI
WAIT19 CALL KEYSCAN
BTFSS PORTB，4
GOTO WAIT19 ;等键松开
GOTO DENJIAN ;新一次计时开始
END