ARM·存储器配置

首先补充一下基本的知识：

运行地址->链接地址

在SRAM或者SDRAM中执行程序时，PC指向这个地址，那么命令就应该在这个地址里面 ；

加载地址->存储地址

程序保存在NAND FLSAH中的地址

位置无关码：B，BL，MOV

位置有关码：LDR PC，=Label

sdram.bin : head.S leds.c

arm-linux-gcc -c -o head.o head.S

arm-linux-gcc -c -o leds.o leds.c

arm-linux-ld -Ttext 0x30000000 head.o leds.o -o sdram_elf

arm-linux-objcopy -O binary -S sdram_elf sdram.bin

arm-linux-objdump -D -m arm sdram_elf > sdram.dis

clean: rm -f sdram.dis sdram.bin sdram_elf *.o

这里我们看到这一句“arm-linux-ld -Ttext 0x30000000 head.o leds.o -o sdram_elf ”，说明该程序是放在0x3000 0000的地址中的，由mini2440存储地址可知，那里是SDRAM的首地址

（配置SDRAM）

@*************************************************************************

@ File：head.S

@ 功能：设置SDRAM，将程序复制到SDRAM，然后跳到SDRAM继续执行

@*************************************************************************

.equ MEM_CTL_BASE, 0x48000000

.equ SDRAM_BASE, 0x30000000

.text

.global _start

_start:

bl disable_watch_dog @ 关闭WATCHDOG，否则CPU会不断重启

bl memsetup @ 设置存储控制器

bl copy_steppingstone_to_sdram @ 复制代码到SDRAM中

ldr pc, =on_sdram @ 跳到SDRAM中继续执行

on_sdram:

ldr sp, =0x34000000 @ 设置堆栈

bl main

halt_loop:

b halt_loop

disable_watch_dog:

@ 往WATCHDOG寄存器写0即可

mov r1, #0x53000000

mov r2, #0x0

str r2, [r1]

mov pc, lr @ 返回

copy_steppingstone_to_sdram:

@ 将Steppingstone的4K数据全部复制到SDRAM中去

@ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000

mov r1, #0

ldr r2, =SDRAM_BASE

mov r3, #4*1024

1:

ldr r4, [r1],#4 @ 从Steppingstone读取4字节的数据，并让源地址加4

str r4, [r2],#4 @ 将此4字节的数据复制到SDRAM中，并让目地地址加4

cmp r1, r3 @ 判断是否完成：源地址等于Steppingstone的未地址？

bne 1b @ 若没有复制完，继续

mov pc, lr @ 返回

memsetup:

@ 设置存储控制器以便使用SDRAM等外设

mov r1, #MEM_CTL_BASE @ 存储控制器的13个寄存器的开始地址

adrl r2, mem_cfg_val @ 这13个值的起始存储地址

add r3, r1, #52 @ 13*4 = 54

1:

ldr r4, [r2], #4 @ 读取设置值，并让r2加4

str r4, [r1], #4 @ 将此值写入寄存器，并让r1加4

cmp r1, r3 @ 判断是否设置完所有13个寄存器

bne 1b @ 若没有写成，继续

mov pc, lr @ 返回

.align 4

mem_cfg_val:

@ 存储控制器13个寄存器的设置值

.long 0x22011110 @ BWSCON

.long 0x00000700 @ BANKCON0

.long 0x00000700 @ BANKCON1

.long 0x00000700 @ BANKCON2

.long 0x00000700 @ BANKCON3

.long 0x00000700 @ BANKCON4

.long 0x00000700 @ BANKCON5

.long 0x00018005 @ BANKCON6

.long 0x00018005 @ BANKCON7

.long 0x008C07A3 @ REFRESH

.long 0x000000B1 @ BANKSIZE

.long 0x00000030 @ MRSRB6

.long 0x00000030 @ MRSRB7

sdram_elf: file format elf32-littlearm

Disassembly of section .text:

30000000 <_start>:

30000000: eb000005 bl 3000001c

30000004: eb000010 bl 3000004c

30000008: eb000007 bl 3000002c

3000000c: e59ff090 ldr pc, [pc, #144] ; 300000a4

30000010 :

30000010: e3a0d30d mov sp, #872415232 ; 0x34000000

30000014: eb000035 bl 300000f0

30000018 :

30000018: eafffffe b 30000018

3000001c :

3000001c: e3a01453 mov r1, #1392508928 ; 0x53000000

30000020: e3a02000 mov r2, #0 ; 0x0

30000024: e5812000 str r2, [r1]

30000028: e1a0f00e mov pc, lr

3000002c :

3000002c: e3a01000 mov r1, #0 ; 0x0

30000030: e3a02203 mov r2, #805306368 ; 0x30000000

30000034: e3a03a01 mov r3, #4096 ; 0x1000

30000038: e4914004 ldr r4, [r1], #4

3000003c: e4824004 str r4, [r2], #4

30000040: e1510003 cmp r1, r3

30000044: 1afff