LPC2114启动代码分析

LPC2114启动代码的编写主要包括:
1.异常向量表的建立
2.MCU各种模式堆栈的初始化
3.系统基本的初始化工作
下面分别进行介绍.
(一)ARM相关指令及伪指令
LDR PC,ResetAddr
将ResetAddr标号地址所指的内容传送给PC寄存器
LDR PC,=ResetAddr
将ResetAddr标号地址传送给PC寄存器
ResetAddr DCD ResetInit
为ResetAddr分配一个字的地址空间,以ResetInit初始化,即ResetAddr地址所指的内容为ResetInit标号地址
SvcStackSpace Space SVC_STACK_LENGTH*4
为SvcStackSpace分配一块SVC_STACK_LENGTH*4大小的地址区域,并以0初始化区域内容
(二)异常向量表的建立
异常是有内部或外部源产生的,以引起处理器处理的一个事件,异常出现后，CPU强制从异常类型对应的固定存储地址开始执行程序,如当IRQ中断产生后，CPU强制跳转到0x00000018出执行代码,我们要做的就是在这个代码地址出编写相应的指令，让它顺利执行IRQ中断程序.通常我们会在这里放置一条转移指令,因为0x00000018只给你一个字的编程空间.
程序如下:
AREA vectors,CODE,READONLY
ENTRY
;interrupt vectors
;中断向量表
Reset
LDR PC, ResetAddr
LDR PC, UndefinedAddr
LDR PC, SWI_Addr
LDR PC, PrefetchAddr
LDR PC, DataAbortAddr
DCD 0xb9205f80
LDR PC, [PC, #-0xff0]
LDR PC, FIQ_Addr
ResetAddr DCD ResetInit
UndefinedAddr DCD Undefined
SWI_Addr DCD SoftwareInterrupt
PrefetchAddr DCD PrefetchAbort
DataAbortAddr DCD DataAbort
Nouse DCD 0
IRQ_Addr DCD 0
FIQ_Addr DCD FIQ_Handler
;未定义指令
Undefined
B Undefined
;软中断
SoftwareInterrupt
B SoftwareInterrupt
;取指令中止
PrefetchAbort
B PrefetchAbort
;取数据中止
DataAbort
B DataAbort
;快速中断
FIQ_Handler
STMFD SP!, {R0-R3, LR}
BL FIQ_Exception
LDMFD SP!, {R0-R3, LR}
SUBS PC, LR, #4
IRQ_Addr DCD 0
FIQ_Addr DCD FIQ_Handler
**
**
ResetInit

BL InitStack ;初始化堆栈 Initialize the stack
BL TargetResetInit ;目标板基本初始化 Initialize the target board
;跳转到c语言入口 Jump to the entry point of C program
B __main
我们可以看到,每种异常都有相应的处理程序,如:当系统复位后,程序跳转到0x00000000处执行指令,那么就执行 LDR PC, ResetAddr,及执行ResetInit地址处的代码,这里放置了BL InitStack指令,负责完成各种模式下堆栈的初始化,接着执行BL TargetResetInit,完成目标板基本初始化,最后进入c语言入口，执行main函数.
(三)MCU各种模式堆栈的初始化
由于各种异常模式下都有自身的SP堆栈指针,因此就必须先进入各自的异常模式进行SP的设置,各种模式的切换可以通过改变CPSR来实现,程序如下:
InitStack
MOV R0, LR
;Build the SVC stack
;设置管理模式堆栈
MSR CPSR_c, #0xd3
LDR SP, StackSvc
;Build the IRQ stack
;设置中断模式堆栈
MSR CPSR_c, #0xd2
LDR SP, StackIrq
;Build the FIQ stack
;设置快速中断模式堆栈
MSR CPSR_c, #0xd1
LDR SP, StackFiq
;Build the DATAABORT stack
;设置中止模式堆栈
MSR CPSR_c, #0xd7
LDR SP, StackAbt
;Build the UDF stack
;设置未定义模式堆栈
MSR CPSR_c, #0xdb
LDR SP, StackUnd
;Build the SYS stack
;设置系统模式堆栈
MSR CPSR_c, #0x5f
LDR SP, =StackUsr
MOV PC, R0

**
**
StackSvc DCD SvcStackSpace + (SVC_STACK_LEGTH - 1)* 4
StackIrq DCD IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4
StackFiq DCD FiqStackSpace + (FIQ_STACK_LEGTH - 1)* 4
StackAbt DCD AbtStackSpace + (ABT_STACK_LEGTH - 1)* 4
StackUnd DCD UndtStackSpace + (UND_STACK_LEGTH - 1)* 4
**
**
;/* 分配堆栈空间 */
AREA MyStacks, DATA, NOINIT, ALIGN=2
SvcStackSpace SPACE SVC_STACK_LEGTH * 4 ;Stack spaces for Administration Mode 管理模式堆栈空间
IrqStackSpace SPACE IRQ_STACK_LEGTH * 4 ;Stack spaces for Interrupt ReQuest Mode 中断模式堆栈空间
FiqStackSpace SPACE FIQ_STACK_LEGTH * 4 ;Stack spaces for Fast Interrupt reQuest Mode 快速中断模式堆栈空间
AbtStackSpace SPACE ABT_STACK_LEGTH * 4 ;Stack spaces for Suspend Mode 中止义模式堆栈空间
UndtStackSpace SPACE UND_STACK_LEGTH * 4 ;Stack spaces for Undefined Mode 未定义模式堆栈
****
***
AREA Stacks, DATA, NOINIT
StackUsr
说明:MSR CPSR_c, #XX指令完成各种异常模式的切换,如切换到IRQ模式,则执行MSR CPSR_c, #0xd2,而SP的值由SvcStackSpace的地址加上SVC_STACK_LEGTH 的所指的大小而定.
(四)系统基本的初始化工作
完成堆栈初始化后执行BL TargetResetInit,它负责系统一些基本的初始化,如地址重映射,PLL时钟初始化,VIC中断初始化等,具体代码见Easy Arm2100开发版的target.c文件.
最后,执行B __main,__main是ADS的一个系统函数,它负责一些初始化环境然后执行用户的main函数.