PIC16系列单片机的查表

许多读者对 PCL、PCLATH与PC之间的关系不是十分明了, 因此在调用子程序或执行程序跳转时,对出现的程序跑飞现象束手无策。

PC是程序计数器, 在PIC16中档单片机中是13位宽。

PCL是程序计数器的低8位,可读写。在程序执行过程中, 因PC会不断改变, 所以PCL也会跟着改变。同样,改变PCL的值会改变PC的值, 从而实现程序的跳转。

PCLATH是程序计数器的高5位锁存器, 但并不等于PC的高5位。PC的改变并不直接映射到PCLATH,同样,改变PCLATH并不直接改变PC。只有特定的指令PCLATH才会装载到PC中,即CALL、GOTO、ADDWF、PCL及F 指令。

2程序跳转

(1)PC绝对跳转

CALL 或 GOTO 指令可实现程序的绝对跳转。

例:

CALL SUB1
　　GOTO SUB2

说明:　PC的低11位地址来自于操作码,高2位来自于PCLATH的第5位和第4位。因为操作码只包含11位子程序的地址,高2位来自于PCLATH,因此在调用子程序前必须正确设置PCLATH。当然不是每次调用子程序前都要设置PCLATH,但要保证调用子程序前,PCLATH已包含正确的值。

设置PCLATH可使用宏命令：PAGESEL。

例：

PAGESEL　SUB1 　　
　　CALL SUB1

(2)PC相对跳转

用ADDWF 指令可实现程序的相对跳转。

例:

ADDWF PCL,F 　
　　RETLW 0x01
　　RETLW 0X02

说明：PC的低８位地址等于当前的PCL与Ｗ相加后的值,高5位来自于PCLATH的低5位。因此在使用这条指令之前必须正确设置PCLATH,特别注意PCL与Ｗ相加后如果有进位,必须相应地对PCLATH加1。

3查表的实现

虽然PIC16单片机没有专用的查表指令,但可利用ADDWF PCL,F指令实现查表,下面举例说明。

(1)简单的查表程序

程序说明: OFFSET为偏移地址, 假设程序起始地址为0X20, PCL与W相加后不会有进位。

ORG 0X20
MAIN:
　　MOVLW 0X01
　　MOVWF OFFSET
　　CLRF PCLATH
　　CALL LOOK_UP
　　MOVWF VALUE
　　GOTO $
LOOK_UP
　　MOVF OFFSET,W
　　ADDWF PCL,F
　　RETLW 0X01
　　RETLW 0X02
　　RETLW 0X03
　　RETLW 0X04
　　RETLW 0X05
　　RETLW 0X06
　　……

(2)通用的的查表程序

程序说明: OFFSET为偏移地址,可将MAIN、LOOK_UP、TABLE三个子程序置于程序区任意位置。

MAIN
　　MOVLW 0X05
　　MOVWF OFFSET
　　PAGESEL LOOK_UP
　　CALL LOOK_UP
　　MOVWF VALUE
　　GOTO $
LOOK_UP
　　MOVLW HIGH(TABLE)
　　MOVWF PCLATH
　　MOVLW LOW(TABLE)
　　ADDWF OFFSET,W
　　BTFSC STATUS,C
　　INCF PCLATH,F
　　MOVF OFFSET,W
TABLE
　　ADDWF PCL,F
dt 0x1,0x2,0x3,0x4,0x5,0x6,0x7,0x8,0x9,0x0a,0x0b,0x0c,0x0D,0x0E,0x0F ……

(3)大于256个数据的查表程序

程序说明: OFFSETH、OFFSETL为偏移地址的高8位和低8位。可将MAIN、LOOK_UP、TABLE三个子程序置于程序区任意位置。

MAIN
　　MOVLW 0X00
　　MOVWF OFFSETH
　　MOVLW 0X10
　　MOVWF OFFSETL
　　PAGESEL LOOK_UP
　　CALL LOOK_UP
　　MOVWF VALUE
LOOK_UP
　　MOVLW HIGH(TABLE)
　　ADDWF OFFSETH,W
　　MOVWF PCLATH
　　MOVLW LOW(TABLE)
　　ADDWF OFFSETL,W
　　BTFSC STATUS,C
　　INCF PCLATH,F
　　MOVF OFFSETL,W
TABLE
　　ADDWF PCL,F
　　dt 0x1,0x2,0x3,0x4,0x5,0x6,0x7,0x8,0x9,0x0a,0x0b,0x0c,0x0D,0x0E,0x0F
　　dt 0x00,0x1,0x2,0x3,0x4,0x5,0x6,0x7,0x8,0x9,0x0a,0x0b,0x0c,0x0d,0x0e
　　dt 0x1,0x2,0x3,0x4,0x5,0x6,0x7,0x8,0x9,0x0a,0x0b,0x0c,0x0d,0x0e,0x00
　　dt 0x00,0x1,0x2,0x3,0x4,0x5,0x6,0x7,0x8,0x9,0x0a,0x0b,0x0c,0x0d,0x0e